Creating Alexa Skills for IoT and Nodemcu - Part 2 AWS IoT

Connecting Nodemcu to AWS IoT

This is part two of a series of posts showing how I setup a AWS based solution to allow Alexa to read data collected by Nodemcu with DHT temperature and humidity sensors. The design is discussed in part one of this series.

Go to Part 1 - Design

Overview

I recommend reviewing my first post in this series, so you can understand the gameplan... but here's the short version. We will create and configure three separate services in AWS. An Alexa Skill for voice commands, a AWS Lambda function that will act as a middle man, and AWS IoT for storing the current state of the Nodemcu sensors.

DISCLAIMER: This guide uses a work around to allow Nodemcu to communicate directly with AWS IoT. The work around uses API keys that will be written in cleartext on the Nodemcu. Proceed at your own discretion.

Goals

• Configure an IoT Thing
• Setup a security policy and user that can write data to the Thing Shadow via the REST API
• Ensure the policy limits access to only one Thing Shadow and is set to write only
• Wire up our Nodemcu and DHT sensor
• Collect sensor data and write it to the Thing Shadow

Prep

Parts and Components

I have linked the tools and components I used to build this project. I personally own each item linked below.

• (1) Nodemcu http://amzn.to/2E8xF7t
• (1) DHT11 http://amzn.to/2nGV1XN or DHT22 http://amzn.to/2C2O47P
• (1) 4.7K - 10K Resistor http://amzn.to/2C4xTH4(only needed if you have a 4 pin DHT sensor)
• Breadboard Jumper Wires http://amzn.to/2nGuYjy
• (1) Breadboard http://amzn.to/2sayXcw (small cheap ones work great for simple experiments with Nodemcu)
• USB Micro B cable http://amzn.to/2BMAj1h (the same that a android phone uses)
• USB Power Adapter http://amzn.to/2C2sXCw

Tools

• Arduino IDE
• Some good music

AWS

I considered showing how to setup the appropriate accounts on AWS, but it seems there are plenty of good resources to show how to do that. Put your google-fu skills to work or take a wild stab at it.

• Create an AWS Account

AWS IoT is free for 12 months at 250K messages a month.

Steps - AWS IoT

AWS IoT refers to devices as Things. We will setup our Nodemcu with DHT11/22 as a Thing within AWS IoT.

• Login to the AWS Console > Select US East (N. Virginia)
• Search AWS IoT > Select AWS IoT

• Select Manage > Things > Create > Create a single thing

• Enter device information > Next 
• I am sticking to the bare minimum for this guide, so I will enter a name only
• Type allows you to assign a template that includes attributes specific to your device
• Groups are for easier management of your devices

• Create thing without certificate
• Remember we will be using the AWS IoT SDK to establish connectivity because the Nodemcu does not support TLS 1.2
• The more robust approach would be to put a IoT hub/broker into the solution.
• You can select the Thing from the Manage > Things pane. From here you can view things such are the Amazon Resource Name and Shadow state.

• Leave you web browser tab open, because we will be coming back to AWS IoT in future steps.

At this point we have a Thing defined in AWS IoT. Don't get all excited yet. We next need to setup AWS access controls using the IAM console.

Steps - Setup Access Controls

What we need to do here is create a API user and security profile that will allow the Nodemcu to connect to IoT, update the Thing Shadow, and have the ability to do nothing else.

Creat the Security Policy

• Use the same method you found AWS IoT to find and access AWS IAM
• Select Policies > Create Policy
• In the visual editor
• Choose a service > Search IoT  > Select IoT
• Actions > Search Shadow > Select UpdateThingShadow
• Resources > Specific > Add ARN > and paste the ARN for the Thing as shown in the screen host above > Add > Review Policy
• Name the Policy > Create the Policy
• Because this policy is for a one to one relationship I make the name very explicit such as "node_office_UpdateThingShadow"

Create the User

• From the main console page of IAM, Select Users > Add User
• Enter a name that your Nodemcu will use > Select Programmatic sccess > Next Permissions
• Select Attach existing policies directly > Search the Policy name you created above and Select it > Next Review > Create User
• Now you need to make note of the Access key ID and Secret access key

You can always come back to grab the key info again.

Alrighty! Our IoT Thing Shadow is ready and we have an API user that can write data to that Shadow. Let's get the Nodemcu wired up and programmed so we can see a result.

Steps - Setup the Nodemcu with DHT Sensor

• Wire up the Nodemcu and DHT sensor

Here is a diagram of the physical wiring. Omit the 4.7K - 10K resistor if you have a 3 pin DHT. The small breadboards I linked above will fit the Nodemcu and a couple sensors perfectly.They also have double-sided tape for mounting your experiments easily.

We can move on to setting up Arduino to program the Nodemcu.

Steps - Setup Arduino

These steps require ESP8266 2.3.0 library to be installed in Arduino. You can review those steps in my blog post Hacking the Sonoff Wifi Switch - Part 2.

• Open Arduino > Sketch > Include Library > Manage Libraries
• Search and install "AWS-SDK-ESP8266"
• There is more info available on Roman Schmitz github page

• Search and install "DHT sensor library" by Adafruit
• I have not yet tried the "DHT sensor library for ESPx" if you have used it drop me a comment.

And "Adafruit Unified Sensor"

We are ready to review the code and program the Nodemcu.

Code

Credit goes to Roman Schmitz for the orignal AWS code example. I have just modified it to take DHT data and send it to the IoT in the correct JSON format.

Also I want to say thanks to the esp8266 library team. The dateTimeProvider and httpClient functions are saving me a lot of lines of code.

ONE LAST MENTION ABOUT SECURITY: It is not a good idea to include keys, secrets, or passwords directly in code. While there are some ways to store credentials outside of the main body of this sketch it won't fix the issue that all the sensitive data will be placed in cleartext on the Nodemcu. Mongoose OS features flash encryption, but I havent tried it out on a Nodemcu yet.

You will need the following info to use this sketch:

• Thing HTTPS API endpoint
• Manage > Things > your_thing > Interact
• Thing Shadow path in the format "/things/your_thing/shadow"
• AWS API Key ID
• AWS API Secret Key

What are we doing here?

This sketch will connect your Nodemcu to your wifi network, configure the AWS client, collect the current temperature and humidity, and write that to the Thing Shadow in IoT. This is repeated every 60000 milliseconds or 60 seconds. 

You can change the delay to suit your needs (especially during testing), but before you change the delay you should calculate the how many connections your device(s) will be making to IoT. 250K messages per month is the magic number.

#include <ESP8266WiFi.h>
#include <AmazonIOTClient.h>
#include <ESP8266AWSImplementations.h>
#include <AWSFoundationalTypes.h>
#include <DHT.h>

Esp8266HttpClient httpClient;
Esp8266DateTimeProvider dateTimeProvider;

AmazonIOTClient iotClient;
ActionError actionError;

// DHT Sensor setup
#define DHTPIN D1
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

char *ssid="YOUR SSID";
char *password="YOUR PASSWORD";

void setup() {
  Serial.begin(115200);
  delay(10);

  // LED on nodemcu
  pinMode(BUILTIN_LED, OUTPUT);

  // DHT Sensor
  dht.begin();

  // Connect to WAP
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  iotClient.setAWSRegion("us-east-1");
  iotClient.setAWSEndpoint("amazonaws.com");
  iotClient.setAWSDomain("YOUR REST THING API ENDPOINT");
  iotClient.setAWSPath("YOUR THING SHADOW PATH");
  iotClient.setAWSKeyID("YOUR ACCESS KEY ID");
  iotClient.setAWSSecretKey("YOUR SECRET ACCESS KEY");
  iotClient.setHttpClient(&httpClient);
  iotClient.setDateTimeProvider(&dateTimeProvider);
}

void loop(){
  float t = dht.readTemperature(true);
  char temp[10];
  dtostrf(t,1,2,temp);
 
  float h = dht.readHumidity();
  char hum[10];
  dtostrf(h,1,2,hum);

  MinimalString shadow = ("{\"state\":{\"reported\":{\"temperature\":" + String(temp) + ",\"humidity\":" + String(hum) + "}}}").c_str();

  char* result = iotClient.update_shadow(shadow, actionError);
  Serial.print(result);

  delay(60000);
}

Steps - Program the Nodemcu

• In Arduino, insert the sketch code and input your wifi creds and api keys
• Nodemcu programming settings are as follows
• Board NodeMCU 1.0 (ESP-12E Module)
• I use all other defaults
• Of course make sure your COM is set
• Open Serial Monitor on your COM
• Upload the code
• Watch serial monitor for a minute and make sure it is outputting as expected.
• Disconnect the Nodemcu from power and reconnect

Program Result

If things go well you will see the Nodemcu connect to your wifi and output its IP. Then it will show the connections it is making to AWS IoT.

Result

Now if everything is working as expected we will see the Thing Shadow being updated.

• Navigate back to AWS IoT > Manage > Things > Your Thing > Shadow

Coolio. We are so totally going to make this work.

Next Steps

In the next post we will cap things off by creating a way for Alexa to read these values to us. If you want to see the whole concept and design diagram check out part one of this series.

Go to Part 1 - Design